1.正则表达式(Regular Expression)基础
正则表达式是通用的文本搜索和处理方案，它的知识不是VBA独有的，基本上每种语言都内置了正则表达式的功能。正则表达式的基础知识不是这里的重点，需要的朋友可以Google一下，或者参看下面的一些入门教程：
http://deerchao.net/tutorials/regex/regex.htm
http://www.regexlab.com/zh/regref.htm
http://www.williamlong.info/archives/433.html
2.VBA中的正则表达式应用
在VBA中使用正则表达式，可以通过下列途径实现：
创建正则表达式对象：
前期绑定：在VBA代码编辑器中的"Tools"菜单中，选中"References..."，然后引用Microsoft VBScript Regular Expressions 5.5类库，然后直接定义对象：Dim reg As New RegExp。
后期绑定：使用CreateObject方法定义对象：CreateObject("VBSCRIPT.REGEXP")。
前一种方式的优点是可以有编辑器的Intellisense支持。
RegExp对象的属性：
Global - 设置或返回一个 Boolean 值，该值指明在整个搜索字符串时模式是全部匹配还是只匹配第一个。如果搜索应用于整个字符串，Global 属性的值应该为 True，否则其值为 False。默认的设置为True。
Multiline - 返回正则表达式是否具有标志m, 缺省值为False。如果指定的搜索字符串分布在多行，这个属性是要设置为True的。
IgnoreCase - 设置或返回一个Boolean值，指明模式搜索是否区分大小写。如果搜索是区分大小写的，则 IgnoreCase 属性应该为False；否则应该设为True。缺省值为True。
Pattern - 设置或返回被搜索的正则表达式模式。 被搜索的正则字符串表达式。它包含各种正则表达式字符。
RegExp对象的方法：
Execute - 对指定的字符串执行正则表达式搜索。需要传入要在其上执行正则表达式的文本字符串。正则表达式搜索的设计模式是通过 RegExp对象的Pattern来设置的。Execute方法返回一个Matches集合，其中包含了在string中找到的每一个匹配的Match对 象。如果未找到匹配，Execute将返回空的Matches集合。
Replace - 替换在正则表达式查找中找到的文本。
Test - 对指定的字符串执行一个正则表达式搜索，并返回一个 Boolean 值指示是否找到匹配的模式。RegExp.Global属性对Test方法没有影响。如果找到了匹配的模式，Test方法返回True；否则返回False。
MatchCollection对象与Match对象
匹配到的所有对象放在MatchCollection集合中，这个集合对象只有两个只读属性：
Count：匹配到的对象的数目
Item：集合的又一通用方法，需要传入Index值获取指定的元素。
一般，可以使用For Each语句枚举集合中的对象。集合中对象的类型是Match。
Match对象有以下几个只读的属性：
FirstIndex - 匹配字符串在整个字符串中的位置，值从0开始。
Length - 匹配字符串的长度。
Value - 匹配的字符串。
SubMatches - 集合，匹配字符串中每个分组的值。作为集合类型，有Count和Item两个属性。
结尾两个示例：
' 正则表达式示例1 提取字符串中的数字
Sub getNum1()
' 这种使用方式需要"工具""引用"
' 引用Microsoft VBScript Regular Expressions 5.5类库
Dim reg As New RegExp
With reg
.Global = True
.IgnoreCase = True
.Pattern = "\d+"
End With
Dim mc As MatchCollection
Dim m As Match
Set mc = reg.Execute("123aaaaa987uiiui999")
For Each m In mc
MsgBox m.Value + 1
Next
End Sub
' 正则表达式示例2 用"字符串"替换原字符串中符合匹配模式的部分
Sub getNum2()
Dim arr
arr = Split("A12B-R1E2W-E1T-R2T-Q1B2Y3U4D", "-") ' split(字符串,"分隔符")拆分字符串
MsgBox "arr(0)=" & arr(0) & ";arr(1)=" & arr(1)
MsgBox Join(arr, ",") ' join(数组,"分隔符")用分隔连接数组的每个元成一个字符串
Dim arrStr() As String
ReDim arrStr(LBound(arr) To UBound(arr)) ' 为动态数组分配存储空间
With CreateObject("VBSCRIPT.REGEXP") ' 生成一个正则表达式对象实例
For i = LBound(arr) To UBound(arr)
.Global = True ' 设置全局可用，即替换所有符合匹配模式的字符串
.Pattern = "[^A-Z]" ' 匹配模式为非大写字母
arrStr(i) = .Replace(arr(i), "") ' 将arr(i)字符串中符合匹配模式的部分替换为空字符
Next
End With
Cells.ClearContents
Cells(1, 1).Resize(UBound(arr) + 1, 1) = Application.WorksheetFunction.Transpose(arrStr())
End Sub
示例2
'<body>タグに onLoad="commonOnload()"があるか。
Private Function SubCheckBodyCommonOnload(pageStr)
Dim reg As Object
Set reg = CreateObject("VBscript.RegExp")
With reg
.Global = True
.IgnoreCase = True
.Pattern = "(<)([\s]*)(body)([\w\W]*)(onLoad)([\s]*)=([\s]*)(\W)([\s]*)(commonOnload\()([\s]*)(\))"
End With
SubCheckBodyCommonOnload = reg.test(pageStr)
End Function
原载
http://justsee.iteye.com/blog/1468745#
转载请注明原文地址: https://ju.6miu.com/read-971705.html
